Skip to content
Snippets Groups Projects
Commit 76626435 authored by fontchas5's avatar fontchas5
Browse files

ajout

parent 23783ddb
No related branches found
No related tags found
No related merge requests found
# Condensateur
Un exemple simple de condensateur en cylindrique : problème axisymétrique sur une demie-géométrie avec boîte infinie. Formulation en potentiel scalaire électrique.
![Image](./condo/condo.png)
Si vous voulez l'utilisez sur smartphone, vous pouvez télécharger le fichier `*.zip` et l'ouvrir avec l'application Onelab.
File added
Ressources-Onelab/Condensateur/condo/condo.png

15.3 KiB

Include "data_condo.geo";
lcC = epd/10;
lcdom = Rdom/10;
Point(1) = {Ri,0,0,lcC};
Point(2) = {Ri,h/2,0,lcC};
Point(3) = {Ri+ep,h/2,0,lcC};
Point(4) = {Ri+ep,0,0,lcC};
Point(5) = {Ri+ep+epd,0,0,lcC};
Point(6) = {Ri+ep+epd,h/2,0,lcC};
Point(7) = {Ri+2*ep+epd,h/2,0,lcC};
Point(8) = {Ri+2*ep+epd,0,0,lcC};
Point(9) = {Rdom,0,0,lcdom};
Point(10) = {0,Rdom,0,lcdom};
Point(11) = {0,0,0,lcC};
For i In {1:8}
Line(i) = {i,i+1};
EndFor
Circle(9) = {9,11,10};
Line(10) = {10,11};
Line(11) = {11,1};
Line(12) = {3,6};
Line Loop(1) = {1,2,12,6,7,8,9,10,11};
Plane Surface (1) = {1};
Line Loop(2) = {3,4,5,-12};
Surface(2) = {2};
Point(12) = {Rbi,0,0,lcdom};
Point(13) = {0,Rbi,0,lcdom};
Line(13) = {9,12};
Circle(14) = {12,11,13};
Line(15) = {13,10};
Line Loop(3) = {13,14,15,-9};
Plane Surface(3) = {3};
Physical Surface(AIR) = {1};
Physical Surface(DIELECTRIQUE) = {2};
Physical Surface(BOITEINF) = {3};
Physical Line(DELTAV) = {1,2,3};
Physical Line(MASSE) = {5,6,7};
Color White { Surface{1,3}; }
Color LightGray {Surface{2}; }
Include "data_condo.geo";
Group{
Domaine = Region[{AIR,DIELECTRIQUE,BOITEINF}];
Dielectrique = Region[{DIELECTRIQUE}];
BoiteInf = Region[{BOITEINF}];
Masse = Region[{MASSE}];
DeltaV = Region[{DELTAV}];
}
Function{
eps0 = 8.854187818e-12;
epsr = 9.8;
eps[#{AIR,BOITEINF}] = eps0;
eps[#{DIELECTRIQUE}] = eps0*epsr;
V1 = 1;
}
Jacobian{
{ Name Jvol;
Case {
{ Region BoiteInf ; Jacobian VolAxiSphShell{Rdom, Rbi}; }
{ Region All ; Jacobian VolAxi ; }
}
}
}
Integration {
{ Name Integ;
Case {
{Type Gauss;
Case {
{ GeoElement Line ; NumberOfPoints 2; }
{ GeoElement Triangle ; NumberOfPoints 6; } }
}
}
}
}
Constraint {
{Name TensionsImposees ;
Case {
{ Region Masse ; Type Assign ; Value 0. ; }
{ Region DeltaV ; Type Assign ; Value V1 ; }
}
}
}
FunctionSpace {
{ Name Hgrad ; Type Form0 ;
BasisFunction {
{ Name sn ; NameOfCoef vn ; Function BF_Node ;
Support Region[{Domaine}] ; Entity NodesOf[All] ; }
}
Constraint {
{ NameOfCoef vn ; EntityType NodesOf ; NameOfConstraint TensionsImposees ; }
}
}
}
Formulation {
{ Name Electrostat ; Type FemEquation ;
Quantity {
{ Name v ; Type Local ; NameOfSpace Hgrad ; }
}
Equation {
Galerkin { [ eps[]*Dof{Grad v} , {Grad v} ] ;
In Domaine ; Jacobian Jvol ; Integration Integ ; }
}
}
}
Resolution {
{ Name analyse ;
System {
{ Name Sys ; NameOfFormulation Electrostat ; }
}
Operation {
Generate[Sys] ;
Solve[Sys] ;
SaveSolution[Sys] ;
}
}
}
PostProcessing {
{ Name PostProc ; NameOfFormulation Electrostat ;
Quantity {
{ Name v ; Value { Term { [ {v} ] ; In Domaine ; Jacobian Jvol ; } } }
{ Name e ; Value { Term { [ -{Grad v} ] ; In Domaine ; Jacobian Jvol ; } } }
{ Name d ; Value { Term { [ -eps[]*{Grad v} ] ; In Domaine ; Jacobian Jvol ; } } }
{ Name nrj ; Value { Integral { [ 2*Pi*eps[]*SquNorm[{Grad v}] ] ; In Domaine ;
Jacobian Jvol ; Integration Integ ;} } }
{ Name C ; Value { Integral { [ 4*Pi*eps[]*SquNorm[{Grad v}]/(V1^2) ] ; In Domaine ;
Jacobian Jvol ; Integration Integ ;} } }
}
}
}
PostOperation PostOp UsingPost PostProc {
Print[ v, OnElementsOf Domaine, File "v.pos"] ;
Print[ d, OnElementsOf Domaine, File "d.pos"] ;
Print[ e, OnElementsOf Domaine, File "e.pos"] ;
Print[ nrj[Domaine], OnGlobal, File "nrj.dat",
SendToServer "Modele/Resultats/1Energie (J)", Color "AliceBlue" ];
Print[ C[Domaine], OnGlobal, File "capa.dat",
SendToServer "Modele/Resultats/2Capa (F)", Color "AliceBlue" ];
}
\ No newline at end of file
// Données du problème
// grandeurs géométriques
ep = 0.5e-3;
Ri = 1e-2;
epd = 1e-2;
h = 5e-2;
Rdom = 1.2*Sqrt[(Ri+2*ep+epd)^2+(h/2)^2];
ebi = Rdom/10;
Rbi = Rdom+ebi;
// Numéros régions physiques
AIR = 2000;
DIELECTRIQUE = 2001;
BOITEINF = 2002;
MASSE = 1000;
DELTAV = 1001;
<?xml version="1.0" encoding="utf-8"?>
<models>
<model>
<title>Condensateur</title>
<summary>Un demi-condensateur en cylindrique avec boîte infinie.</summary>
<file type="pro">condo_cylindrique.pro</file>
<preview type="png">condo.png</preview>
<url>https://cours.jufont.net/ensem/mef-emag/mefem/electrostat/</url>
</model>
</models>
<?xml version="1.0" encoding="utf-8"?>
<models>
<model>
<title>Condensateur</title>
<summary>Un demi-condensateur en cylindrique avec boîte infinie.</summary>
<file type="pro">condo_cylindrique.pro</file>
<preview type="png">condo.png</preview>
<url>https://cours.jufont.net/ensem/mef-emag/mefem/elctrostat/</url>
</model>
</models>
0% Loading or .
You are about to add 0 people to the discussion. Proceed with caution.
Please register or to comment